home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Apple II Magazines (PO)
/
Nibble Volume 10, No. 10 (1989-10)(MindCraft Publishing)(Side A)[a].zip
/
Nibble Volume 10, No. 10 (1989-10)(MindCraft Publishing)(Side A)[a].po
/
TITLE.LOAD.S
< prev
next >
Wrap
Text File
|
1996-12-24
|
2KB
|
67 lines
*-------------------------------------------------*
* GS.STARTUP SOURCE CODE - By Peter Stubbs *
* Copyright(c) 1989 MindCraft Publ. Corp. *
* This program will load and display a Super Res *
* title screen during the ProDOS 16 boot process *
*-------------------------------------------------*
* MERLIN 816 ASSEMBLER *
*-------------------------------------------------*
REL ;Tell Merlin - relocatable file
DSK PIC.LOAD.L ;assemble link file under this name
* Equates
PRODOS EQU $E100A8
OPEN EQU $10
READ EQU $12
CLOSE EQU $14
MX %00 ;Tel Merlin we're in 16 bits
PHB ;Save data bank
PHK ;Move program bank
PLB ; to data bank
JSL PRODOS
DA OPEN ;Open BOOT.PIC
ADRL OPEN_PRM
BCS ERR ;Exit if there was an error
LDA OPEN_PRM ;Get REFNUM
STA READ_PRM ;Store it in read
STA CLS_PRM ; and close parm tables
SEP #$20 ;8 bit accumulator
LDAL $E1C029 ;Read NEWVIDEO switch
ORA #%01000000 ;Turn on linear addressing
STAL $E1C029
REP #$20 ;16 bit accumulator
JSL PRODOS
DA READ ;Go read in $8000 bytes
ADRL READ_PRM
JSL PRODOS
DA CLOSE ;Close BOOT.PIC
ADRL CLS_PRM
SEP #$20 ;8 bit accumulator
LDAL $E1C029
ORA #%10000000 ;Turn on Super Res display
STAL $E1C029
REP #$20 ;16 bit accumulator
ERR PLB ;Restore bank
RTL ;Exit to caller
OPEN_PRM DA $0000 ;REFNUM - filled by ProDOS
ADRL PATHNAME ;Pointer to pathname
ADRL $0000 ;I/O buffer - filled by ProDOS
READ_PRM DA $0000 ;REFNUM - filled by program
ADRL $E12000 ;Data buffer - Super Res screen
ADRL $8000 ;Bytes to read ($8000 = whole pic)
ADRL $0000 ;Bytes read - filled by ProDOS
CLS_PRM ADRL $0000 ;REFNUM - filled by program
PATHNAME STR '*/SYSTEM/SYSTEM.SETUP/BOOT.PIC'